yuya_takahashi_
教育

Pine講座㊿ バックテスト|ZigZag PA Strategy V4.1 の解説(パターンとフィボナッチによる売買)

FX:EURUSD   ユーロ/米ドル
すごいストラテジーを見つけました。

1.ジグザグを算出
2.フィボナッチを算出
3.ジグザグでパターンを認識
4.パターンとフィボナッチの条件を満たせばエントリー
5.フィボナッチによる利確と損切り

これをひとつのストラテジーで実現しています。
これはめちゃくちゃ勉強になりました。

エリオット波動とかパターン分析の良いところは、

・すばやいエントリーと決済
・明確な値幅が算出できる

あたりだと考えています。

価格を加工すればするほど、
それをエントリーや決済の基準にするのは
難しくなるイメージです。

※ 解説はコードの中で

※ コピペする場合は以下の変更を行ってください
[](全角の角括弧)→(半角の角括弧)
(全角スペース)→(半角スペース)

=====
//@version=2

// ストラテジーの宣言
// ピラミッティングなし、通貨:usd、元金10万ドル
strategy(title='[STRATEGY][RS]ZigZag PA Strategy V4.1', shorttitle='S', overlay=true, pyramiding=0, initial_capital=100000, currency=currency.USD)

//
// 設定項目
////

// 平均足を使うか
useHA    = input(false, title='Use Heikken Ashi Candles')
// 代わりの時間軸を使うか(Alt=altemate?)
useAltTF   = input(true, title='Use Alt Timeframe')
tf     = input('60', title='Alt Timeframe')
// チャートに表示するしない
showPatterns = input(true, title='Show Patterns')
showFib0000 = input(title='Display Fibonacci 0.000:', type=bool, defval=true)
showFib0236 = input(title='Display Fibonacci 0.236:', type=bool, defval=true)
showFib0382 = input(title='Display Fibonacci 0.382:', type=bool, defval=true)
showFib0500 = input(title='Display Fibonacci 0.500:', type=bool, defval=true)
showFib0618 = input(title='Display Fibonacci 0.618:', type=bool, defval=true)
showFib0764 = input(title='Display Fibonacci 0.764:', type=bool, defval=true)
showFib1000 = input(title='Display Fibonacci 1.000:', type=bool, defval=true)

// ジグザグを算出する関数を作成
// 頂点にあたるときのみ、その値を返す
// 頂点以外のときはnaを返す
// ロジック:反対の足が2本連続 → 転換とする
////

zigzag =>
  _isUp = close >= open
  _isDown = close <= open
  _direction = _isUp[1] and _isDown ? -1 : _isDown[1] and _isUp ? 1 : nz (_direction[1])
  _zigzag = _isUp[1] and _isDown and _direction[1] != -1 ? highest(2) : _isDown[1] and _isUp and _direction[1] != 1 ? lowest(2) : na

// ジグザグの算出と描画
// 平均足と時間軸の設定はここで反映
////

_ticker = useHA ? heikenashi(tickerid) : tickerid
sz = useAltTF ? (change(time(tf)) != 0 ? security(_ticker, tf, zigzag ()) : na) : zigzag
plot(sz, title='zigzag', color=black, linewidth=2)

//
// パターンを識別する
////

// ジグザグが発生したときのジグザグの値を取得
x = valuewhen(sz, sz, 4)
a = valuewhen(sz, sz, 3)
b = valuewhen(sz, sz, 2) //3つ前
c = valuewhen(sz, sz, 1) //前々回
d = valuewhen(sz, sz, 0) //前回

xab = (abs(b-a)/abs(x-a))
xad = (abs(a-d)/abs(x-a))
abc = (abs(b-c)/abs(a-b))
bcd = (abs(c-d)/abs(b-c))

// 5つの点の比率からパターンを判断する関数
isBat(_mode)=>
  _xab = xab >= 0.382 and xab <= 0.5
  _abc = abc >= 0.382 and abc <= 0.886
  _bcd = bcd >= 1.618 and bcd <= 2.618
  _xad = xad <= 0.618 and xad <= 1.000  // 0.886
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isAntiBat(_mode)=>
  _xab = xab >= 0.500 and xab <= 0.886  // 0.618
  _abc = abc >= 1.000 and abc <= 2.618  // 1.13 --> 2.618
  _bcd = bcd >= 1.618 and bcd <= 2.618  // 2.0 --> 2.618
  _xad = xad >= 0.886 and xad <= 1.000  // 1.13
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isAltBat(_mode)=>
  _xab = xab <= 0.382
  _abc = abc >= 0.382 and abc <= 0.886
  _bcd = bcd >= 2.0 and bcd <= 3.618
  _xad = xad <= 1.13
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isButterfly(_mode)=>
  _xab = xab <= 0.786
  _abc = abc >= 0.382 and abc <= 0.886
  _bcd = bcd >= 1.618 and bcd <= 2.618
  _xad = xad >= 1.27 and xad <= 1.618
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isAntiButterfly(_mode)=>
  _xab = xab >= 0.236 and xab <= 0.886  // 0.382 - 0.618
  _abc = abc >= 1.130 and abc <= 2.618  // 1.130 - 2.618
  _bcd = bcd >= 1.000 and bcd <= 1.382  // 1.27
  _xad = xad >= 0.500 and xad <= 0.886  // 0.618 - 0.786
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isABCD(_mode)=>
  _abc = abc >= 0.382 and abc <= 0.886
  _bcd = bcd >= 1.13 and bcd <= 2.618
  _abc and _bcd and (_mode == 1 ? d < c : d > c)

isGartley(_mode)=>
  _xab = xab >= 0.5 and xab <= 0.618 // 0.618
  _abc = abc >= 0.382 and abc <= 0.886
  _bcd = bcd >= 1.13 and bcd <= 2.618
  _xad = xad >= 0.75 and xad <= 0.875 // 0.786
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isAntiGartley(_mode)=>
  _xab = xab >= 0.500 and xab <= 0.886  // 0.618 -> 0.786
  _abc = abc >= 1.000 and abc <= 2.618  // 1.130 -> 2.618
  _bcd = bcd >= 1.500 and bcd <= 5.000  // 1.618
  _xad = xad >= 1.000 and xad <= 5.000  // 1.272
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isCrab(_mode)=>
  _xab = xab >= 0.500 and xab <= 0.875  // 0.886
  _abc = abc >= 0.382 and abc <= 0.886  
  _bcd = bcd >= 2.000 and bcd <= 5.000  // 3.618
  _xad = xad >= 1.382 and xad <= 5.000  // 1.618
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isAntiCrab(_mode)=>
  _xab = xab >= 0.250 and xab <= 0.500  // 0.276 -> 0.446
  _abc = abc >= 1.130 and abc <= 2.618  // 1.130 -> 2.618
  _bcd = bcd >= 1.618 and bcd <= 2.618  // 1.618 -> 2.618
  _xad = xad >= 0.500 and xad <= 0.750  // 0.618
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isShark(_mode)=>
  _xab = xab >= 0.500 and xab <= 0.875  // 0.5 --> 0.886
  _abc = abc >= 1.130 and abc <= 1.618  //
  _bcd = bcd >= 1.270 and bcd <= 2.240  //
  _xad = xad >= 0.886 and xad <= 1.130  // 0.886 --> 1.13
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isAntiShark(_mode)=>
  _xab = xab >= 0.382 and xab <= 0.875  // 0.446 --> 0.618
  _abc = abc >= 0.500 and abc <= 1.000  // 0.618 --> 0.886
  _bcd = bcd >= 1.250 and bcd <= 2.618  // 1.618 --> 2.618
  _xad = xad >= 0.500 and xad <= 1.250  // 1.130 --> 1.130
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

is5o(_mode)=>
  _xab = xab >= 1.13 and xab <= 1.618
  _abc = abc >= 1.618 and abc <= 2.24
  _bcd = bcd >= 0.5 and bcd <= 0.625 // 0.5
  _xad = xad >= 0.0 and xad <= 0.236 // negative?
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isWolf(_mode)=>
  _xab = xab >= 1.27 and xab <= 1.618
  _abc = abc >= 0 and abc <= 5
  _bcd = bcd >= 1.27 and bcd <= 1.618
  _xad = xad >= 0.0 and xad <= 5
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isHnS(_mode)=>
  _xab = xab >= 2.0 and xab <= 10
  _abc = abc >= 0.90 and abc <= 1.1
  _bcd = bcd >= 0.236 and bcd <= 0.88
  _xad = xad >= 0.90 and xad <= 1.1
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isConTria(_mode)=>
  _xab = xab >= 0.382 and xab <= 0.618
  _abc = abc >= 0.382 and abc <= 0.618
  _bcd = bcd >= 0.382 and bcd <= 0.618
  _xad = xad >= 0.236 and xad <= 0.764
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

isExpTria(_mode)=>
  _xab = xab >= 1.236 and xab <= 1.618
  _abc = abc >= 1.000 and abc <= 1.618
  _bcd = bcd >= 1.236 and bcd <= 2.000
  _xad = xad >= 2.000 and xad <= 2.236
  _xab and _abc and _bcd and _xad and (_mode == 1 ? d < c : d > c)

// 売りパターンが出現したところに印を表示
plotshape(not showPatterns ? na : isABCD(-1) and not isABCD(-1)[1], text="\nAB=CD", title='Bear ABCD', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0, offset=-2)
plotshape(not showPatterns ? na : isBat(-1) and not isBat(-1)[1], text="Bat", title='Bear Bat', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0, offset=-2)
plotshape(not showPatterns ? na : isAntiBat(-1) and not isAntiBat(-1)[1], text="Anti Bat", title='Bear Anti Bat', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0, offset=-2)
plotshape(not showPatterns ? na : isAltBat(-1) and not isAltBat(-1)[1], text="Alt Bat", title='Bear Alt Bat', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : isButterfly(-1) and not isButterfly(-1)[1], text="Butterfly", title='Bear Butterfly', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : isAntiButterfly(-1) and not isAntiButterfly(-1)[1], text="Anti Butterfly", title='Bear Anti Butterfly', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : isGartley(-1) and not isGartley(-1)[1], text="Gartley", title='Bear Gartley', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : isAntiGartley(-1) and not isAntiGartley(-1)[1], text="Anti Gartley", title='Bear Anti Gartley', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : isCrab(-1) and not isCrab(-1)[1], text="Crab", title='Bear Crab', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : isAntiCrab(-1) and not isAntiCrab(-1)[1], text="Anti Crab", title='Bear Anti Crab', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : isShark(-1) and not isShark(-1)[1], text="Shark", title='Bear Shark', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : isAntiShark(-1) and not isAntiShark(-1)[1], text="Anti Shark", title='Bear Anti Shark', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : is5o(-1) and not is5o(-1)[1], text="5-O", title='Bear 5-O', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : isWolf(-1) and not isWolf(-1)[1], text="Wolf Wave", title='Bear Wolf Wave', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : isHnS(-1) and not isHnS(-1)[1], text="Head and Shoulders", title='Bear Head and Shoulders', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : isConTria(-1) and not isConTria(-1)[1], text="Contracting Triangle", title='Bear Contracting triangle', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)
plotshape(not showPatterns ? na : isExpTria(-1) and not isExpTria(-1)[1], text="Expanding Triangle", title='Bear Expanding Triangle', style=shape.labeldown, color=maroon, textcolor=white, location=location.top, transp=0)

// 買いパターンが出現したところに印を表示
plotshape(not showPatterns ? na : isABCD(1) and not isABCD(1)[1], text="AB=CD\n", title='Bull ABCD', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isBat(1) and not isBat(1)[1], text="Bat", title='Bull Bat', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isAntiBat(1) and not isAntiBat(1)[1], text="Anti Bat", title='Bull Anti Bat', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isAltBat(1) and not isAltBat(1)[1], text="Alt Bat", title='Bull Alt Bat', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isButterfly(1) and not isButterfly(1)[1], text="Butterfly", title='Bull Butterfly', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isAntiButterfly(1) and not isAntiButterfly(1)[1], text="Anti Butterfly", title='Bull Anti Butterfly', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isGartley(1) and not isGartley(1)[1], text="Gartley", title='Bull Gartley', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isAntiGartley(1) and not isAntiGartley(1)[1], text="Anti Gartley", title='Bull Anti Gartley', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isCrab(1) and not isCrab(1)[1], text="Crab", title='Bull Crab', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isAntiCrab(1) and not isAntiCrab(1)[1], text="Anti Crab", title='Bull Anti Crab', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isShark(1) and not isShark(1)[1], text="Shark", title='Bull Shark', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isAntiShark(1) and not isAntiShark(1)[1], text="Anti Shark", title='Bull Anti Shark', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : is5o(1) and not is5o(1)[1], text="5-O", title='Bull 5-O', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isWolf(1) and not isWolf(1)[1], text="Wolf Wave", title='Bull Wolf Wave', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isHnS(1) and not isHnS(1)[1], text="Head and Shoulders", title='Bull Head and Shoulders', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isConTria(1) and not isConTria(1)[1], text="Contracting Triangle", title='Bull Contracting Triangle', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)
plotshape(not showPatterns ? na : isExpTria(1) and not isExpTria(1)[1], text="Expanding Triangle", title='Bull Expanding Triangle', style=shape.labelup, color=green, textcolor=white, location=location.bottom, transp=0)

//前回と前回のジグザグの値からフィボナッチを描画
fib_range = abs(d-c)
fib_0000 = not showFib0000 ? na : d > c ? d-(fib_range*0.000):d+(fib_range*0.000)
fib_0236 = not showFib0236 ? na : d > c ? d-(fib_range*0.236):d+(fib_range*0.236)
fib_0382 = not showFib0382 ? na : d > c ? d-(fib_range*0.382):d+(fib_range*0.382)
fib_0500 = not showFib0500 ? na : d > c ? d-(fib_range*0.500):d+(fib_range*0.500)
fib_0618 = not showFib0618 ? na : d > c ? d-(fib_range*0.618):d+(fib_range*0.618)
fib_0764 = not showFib0764 ? na : d > c ? d-(fib_range*0.764):d+(fib_range*0.764)
fib_1000 = not showFib1000 ? na : d > c ? d-(fib_range*1.000):d+(fib_range*1.000)
plot(title='Fib 0.000', series=fib_0000, color=fib_0000 != fib_0000[1] ? na : black)
plot(title='Fib 0.236', series=fib_0236, color=fib_0236 != fib_0236[1] ? na : red)
plot(title='Fib 0.382', series=fib_0382, color=fib_0382 != fib_0382[1] ? na : olive)
plot(title='Fib 0.500', series=fib_0500, color=fib_0500 != fib_0500[1] ? na : lime)
plot(title='Fib 0.618', series=fib_0618, color=fib_0618 != fib_0618[1] ? na : teal)
plot(title='Fib 0.764', series=fib_0764, color=fib_0764 != fib_0764[1] ? na : blue)
plot(title='Fib 1.000', series=fib_1000, color=fib_1000 != fib_1000[1] ? na : black)

// 代わりの時間軸を使っている場合、その足が更新されるタイミングで背景に黒を入れる
bgcolor(not useAltTF ? na : change(time(tf)) != 0 ? black : na)

//
// 売買のロジック
////

//「fib_rangeに対する指定された比率の幅」を返す関数
f_last_fib( _rate ) => d > c ? d - ( fib_range * _rate ) : d + ( fib_range * _rate )

// ターゲット1の設定項目と初期値
////

// 上から
// 取引量
// エントリーの基準(0.236を超えていない)
// 利益確定幅
// ロスカット幅

target01_trade_size = input(title='Target 1 - Trade size:', type=float, defval=10000.00)
target01_ew_rate  = input(title='Target 1 - Fib. Rate to use for Entry Window:', type=float, defval=0.236)
target01_tp_rate  = input(title='Target 1 - Fib. Rate to use for TP:', type=float, defval=0.618)
target01_sl_rate  = input(title='Target 1 - Fib. Rate to use for SL:', type=float, defval=-0.236)

// ターゲット2の設定
////

target02_active   = input(title='Target 2 - Active?', type=bool, defval=false)
target02_trade_size = input(title='Target 2 - Trade size:', type=float, defval=10000.00)
target02_ew_rate  = input(title='Target 2 - Fib. Rate to use for Entry Window:', type=float, defval=0.236)
target02_tp_rate  = input(title='Target 2 - Fib. Rate to use for TP:', type=float, defval=1.618)
target02_sl_rate  = input(title='Target 2 - Fib. Rate to use for SL:', type=float, defval=-0.236)

// 買いのパターン
buy_patterns_00 = isABCD(1) or isBat(1) or isAltBat(1) or isButterfly(1) or isGartley(1) or isCrab(1) or isShark(1) or is5o(1) or isWolf(1) or isHnS(1) or isConTria(1) or isExpTria(1)
buy_patterns_01 = isAntiBat(1) or isAntiButterfly(1) or isAntiGartley(1) or isAntiCrab(1) or isAntiShark(1)

// 売りのパターン
sel_patterns_00 = isABCD(-1) or isBat(-1) or isAltBat(-1) or isButterfly(-1) or isGartley(-1) or isCrab(-1) or isShark(-1) or is5o(-1) or isWolf(-1) or isHnS(-1) or isConTria(-1) or isExpTria(-1)
sel_patterns_01 = isAntiBat(-1) or isAntiButterfly(-1) or isAntiGartley(-1) or isAntiCrab(-1) or isAntiShark(-1)

// ターゲット1の売買
////

// 買いのパターン & エントリーの基準を満たす → 買いエントリー
// 利確・損切りを超える → 買いの決済
target01_buy_entry = (buy_patterns_00 or buy_patterns_01) and close <= f_last_fib(target01_ew_rate)
target01_buy_close = high >= f_last_fib(target01_tp_rate) or low <= f_last_fib(target01_sl_rate)
strategy.entry('target01_buy', long=strategy.long, qty=target01_trade_size, comment='buy 01', when=target01_buy_entry)
strategy.close('target01_buy', when=target01_buy_close)

// 売りのパターン & エントリーの基準を満たす → 売りエントリー
// 利確・損切りを超える → 売りの決済
target01_sel_entry = (sel_patterns_00 or sel_patterns_01) and close >= f_last_fib(target01_ew_rate)
target01_sel_close = low <= f_last_fib(target01_tp_rate) or high >= f_last_fib(target01_sl_rate)
strategy.entry('target01_sell', long=strategy.short, qty=target01_trade_size, comment='sell 01', when=target01_sel_entry)
strategy.close('target01_sell', when=target01_sel_close)

// ターゲット2の売買
////

target02_buy_entry = target02_active and (buy_patterns_00 or buy_patterns_01) and close <= f_last_fib(target02_ew_rate)
target02_buy_close = target02_active and high >= f_last_fib(target02_tp_rate) or low <= f_last_fib(target02_sl_rate)
strategy.entry('target02_buy', long=strategy.long, qty=target02_trade_size, comment='buy 02', when=target02_buy_entry)
strategy.close('target02_buy', when=target02_buy_close)

target02_sel_entry = target02_active and (sel_patterns_00 or sel_patterns_01) and close >= f_last_fib(target02_ew_rate)
target02_sel_close = target02_active and low <= f_last_fib(target02_tp_rate) or high >= f_last_fib(target02_sl_rate)
strategy.entry('target02_sell', long=strategy.short, qty=target02_trade_size, comment='sell 02', when=target02_sel_entry)
strategy.close('target02_sell', when=target02_sel_close)
=====
コメント: 次の講座
小次郎講師公式インジケーターのお申込
http://bit.ly/2vdSV4Q

小次郎講師のLINE@
http://bit.ly/2VZQFu3

小次郎講師のチャート情報局
http://bit.ly/2GvLAEp
今のユーロドルにトレンドがあるためかもしれませんが、すごい成績ですね。
返信
@tx4187, security関数でごまかしている可能性もあります。もう少し精査してみたいと思います。
返信
yuya_takahashi_ yuya_takahashi_
ジグザグの完成が分かるのが、AltTFのローソク足1本分早いかもしれないですね。
返信
すごい人のコードを読むのは面白いですね!
返信
ホーム 株式スクリーナー FXスクリーナー 仮想通貨スクリーナー 経済指標カレンダー 使い方 チャート機能 価格 ハウスルール モデレーター ウェブサイト&ブローカー向けソリューション ウィジェット チャートソリューション ヘルプ 機能リクエスト ブログ&ニュース よくあるご質問 ウィキ ツイッター
プロフィール プロフィール設定 アカウントとお支払い TradingView コイン マイサポートチケット ヘルプ 公開したアイデア フォロワー フォロー中 プライベートメッセージ チャット サインアウト