yuya_takahashi_
教育

Pine講座㉛ バックテスト|BB Strategy の解説

FX:USDJPY   米ドル/円
TradingView内蔵の BB Stragtegy(ボリンジャーバンドストラテジー)を解説します。
※ 少し書き換えた部分もあります

解説はコード内にて

=====
//Pineスクリプトのバージョンを宣言
//@version=4

//ストラテジーのコードであることを宣言
strategy("Bollinger Bands Strategy", overlay=true)

//変数と設定できる項目を指定
source = close
length = input(20, minval=1)
mult = input(2.0, minval=0.001, maxval=50)

//lengthで指定した値(20)でSMAを算出
basis = sma (source, length)

//lengthで指定した値(20)で標準偏差を算出し、
//multで指定した値(2.0)を乗算する
//初期値だと 2シグマ になる
dev = mult * stdev(source, length)

//SMAにシグマを加算・減算
//±2シグマのバンドができる
upper = basis + dev
lower = basis - dev

//買いエントリーの条件を指定する
//source(終値)が、lower(-2シグマ)を上抜けたとき
buyEntry = crossover(source, lower)

//売りエントリーの条件を指定する
//source(終値)が、upper(+2シグマ)を下抜けたとき
sellEntry = crossunder(source, upper)

//買いエントリーの条件がtrueなら
if ( buyEntry )
//lower(-2シグマ)の価格で逆指値の買いエントリー
//stopやocaなどについては後述
strategy.entry("BBandLE", strategy.long, stop=lower, oca_name="BollingerBands", oca_type=strategy.oca.cancel, comment="BBandLE")
//買いエントリーの条件がfalse
else
//逆指値の買い注文をキャンセル
strategy.cancel(id="BBandLE")

//売りエントリーの条件がtrueなら
if ( sellEntry )
//upper(+2シグマ)の価格で逆指値の売りエントリー
strategy.entry("BBandSE", strategy.short, stop=upper, oca_name="BollingerBands", oca_type=strategy.oca.cancel, comment="BBandSE")
//売りエントリーの条件がfalse
else
//逆指値の売り注文をキャンセル
strategy.cancel(id="BBandSE")

//確認用でBBの各線を描画
plot( basis )
plot( upper )
plot( lower )
=====

strategy.entry("BBandLE", strategy.long, stop=lower, oca_name="BollingerBands", oca_type=strategy.oca.cancel, comment="BBandLE")
を、ちょっとだけ解説します。

最初の "BBandLE" は、この買い注文のIDを指定しています。
IDを指定することで、特定の注文を変更したりキャンセルすることができるようになります。

今回の例でも、strategy.cancel(id="BBandLE") でキャンセルしていますね。

また、strategy.entry( ) は、stop(逆指値)やlimit(指値)を指定することができます。
(指定しない場合はMO(成行)として処理されます)

OCA(One Cancels the All)とは、複数の新規指値・逆指値注文をグループ化し、そのうち1つの注文が約定された場合にその他全ての注文が削除されるものです。この例では、"BollingerBands"というグループを作成しています。
コメント: 次の講座
コメント:
小次郎講師公式インジケーターのお申込
http://bit.ly/2vdSV4Q

小次郎講師のLINE@
http://bit.ly/2VZQFu3

小次郎講師のチャート情報局
http://bit.ly/2GvLAEp

コメント

ホーム 株式スクリーナー FXスクリーナー 仮想通貨スクリーナー 経済指標カレンダー 使い方 チャート機能 価格 友達紹介 ハウスルール ヘルプセンター ウェブサイト&ブローカー向けソリューション ウィジェット チャートソリューション 軽量チャートライブラリ ブログ&ニュース ツイッター
プロフィール プロフィール設定 アカウントとお支払い 友達紹介 コイン マイサポートチケット ヘルプセンター 公開したアイデア フォロワー フォロー中 プライベートメッセージ チャット サインアウト